ESP32 Voice Recorder

				
					#include <Adafruit_NeoPixel.h>
#include <driver/i2s.h>

#define LED_PIN     48       // GPIO pin connected to WS2821 data line
#define NUM_LEDS    1        // Number of LEDs in the strip (usually 1 for built-in)
#define LED_TYPE    NEO_GRB  // uses GRB order

#include "driver/i2s.h"

#define BUTTON 12

#define I2S_MIC_BCLK 47
#define I2S_MIC_LRC 10
#define I2S_MIC_DIN 21
#define I2S_MIC_PORT I2S_NUM_1

#define I2S_SPK_BCLK 2
#define I2S_SPK_LRC 1
#define I2S_SPK_DOUT 38
#define I2S_SPK_SD 4
#define I2S_SPK_PORT I2S_NUM_0

#define SAMPLE_RATE 44100
#define BITS_PER_SAMPLE I2S_BITS_PER_SAMPLE_16BIT
#define BYTES_PER_SAMPLE BITS_PER_SAMPLE / 8
#define REC_DURATION 5
#define BUFFER_SIZE (REC_DURATION * SAMPLE_RATE * BYTES_PER_SAMPLE)

Adafruit_NeoPixel strip(NUM_LEDS, LED_PIN, LED_TYPE + NEO_KHZ800);

int16_t *AudioBuffer = NULL;
size_t bytes_in;
size_t bytes_out;

void setup() {

  strip.begin();
  strip.show(); // Initialize all pixels to 'off'

  Serial.begin(115200);
  delay(500);
  pinMode(BUTTON, INPUT_PULLUP);

  pinMode(I2S_SPK_SD, OUTPUT);  // turn OFF DAC first
  digitalWrite(I2S_SPK_SD, LOW);

  i2s_config_t i2s_mic_config = {
    .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_RX),
    .sample_rate = SAMPLE_RATE,
    .bits_per_sample = BITS_PER_SAMPLE,
    .channel_format = I2S_CHANNEL_FMT_ONLY_LEFT,
    .communication_format = I2S_COMM_FORMAT_STAND_I2S,
    .intr_alloc_flags = 0,
    .dma_buf_count = 8,
    .dma_buf_len = 1024
  };
  i2s_pin_config_t i2s_mic_pin_config = {
    .bck_io_num = I2S_MIC_BCLK, .ws_io_num = I2S_MIC_LRC, .data_out_num = I2S_PIN_NO_CHANGE, .data_in_num = I2S_MIC_DIN
  };
  i2s_driver_install(I2S_MIC_PORT, &i2s_mic_config, 0, NULL);
  i2s_set_pin(I2S_MIC_PORT, &i2s_mic_pin_config);

  i2s_config_t i2s_spk_config = {
    .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_TX),
    .sample_rate = SAMPLE_RATE,
    .bits_per_sample = BITS_PER_SAMPLE,
    .channel_format = I2S_CHANNEL_FMT_ONLY_LEFT,
    .communication_format = I2S_COMM_FORMAT_STAND_I2S,
    .intr_alloc_flags = 0,
    .dma_buf_count = 8,
    .dma_buf_len = 1024
  };
  i2s_pin_config_t i2s_spk_pin_config = {
    .bck_io_num = I2S_SPK_BCLK, .ws_io_num = I2S_SPK_LRC, .data_out_num = I2S_SPK_DOUT, .data_in_num = I2S_PIN_NO_CHANGE
  };

  i2s_driver_install(I2S_SPK_PORT, &i2s_spk_config, 0, NULL);
  i2s_set_pin(I2S_SPK_PORT, &i2s_spk_pin_config);

  // Set up audio buffer in PSRAM
  AudioBuffer = (int16_t *)heap_caps_malloc(BUFFER_SIZE, MALLOC_CAP_SPIRAM);
  if (AudioBuffer == NULL) {
    Serial.println("PSRAM could not be allocated");
    while(1);
  }else{
    Serial.println("Buffer created in PSRAM.");
  }

}

void loop() {

  if(digitalRead(BUTTON) == 0){
    delay(300); // debounce

    Serial.println("Begin Voice Recording...");

    strip.setPixelColor(0, strip.Color(255, 0, 0)); // Red
    strip.show();

    // read I2S MIC
  
    i2s_read(I2S_MIC_PORT, AudioBuffer, BUFFER_SIZE, &bytes_in, portMAX_DELAY);
    Serial.print(bytes_in); Serial.println(" Recorded");

    strip.setPixelColor(0, strip.Color(0, 255, 0)); // Green
    strip.show();

    // Activate DAC
    digitalWrite(I2S_SPK_SD, HIGH);

    // Output Audio Data
    Serial.println("Playing Audio Data");
    i2s_write(I2S_SPK_PORT, AudioBuffer, bytes_in, &bytes_out, portMAX_DELAY);
    Serial.print(bytes_out); Serial.println(" Played");

    // Turn off DAC amp
    digitalWrite(I2S_SPK_SD, LOW);  

    strip.setPixelColor(0, strip.Color(0, 0, 0)); // OFF
    strip.show();

  }

}